path: root/elfeed-conf.el

;;; elfeed-conf.el --- My configurations for elfeed  -*- lexical-binding: t; -*-

;; Copyright (C) 2021  李俊緯

;; Author: 李俊緯 <mmemmew@gmail.com>
;; Keywords: comm, hypermedia

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; This is my configuration file of elfeed, for viewing RSS/atom
;; feeds.

;;; Code:

(use-package "elfeed" 'elfeed)

;;; All feeds

(setq elfeed-feeds
      (list (list "https://blog.tanyakhovanova.com/feed/"
                  'math 'khovanova 'blog)
            ;; (list "https://wiwi.video/feeds/videos.atom?sort=-publishedAt"
            ;;       'wiwi)
            ;; (list "https://wiwikuan.com/index.xml"
            ;;       'wiwi 'blog)
            (list "https://protesilaos.com/codelog.xml"
                  'prot 'code 'emacs)
            (list "https://protesilaos.com/news.xml"
                  'prot 'news)
            (list "https://protesilaos.com/politics.xml"
                  'prot 'politics)
            (list "https://www.youtube.com/feeds/videos.xml?channel_id=UCcXhhVwCT6_WqjkEniejRJQ"
                  'wintergaten 'youtube)
            (list "https://wintergatan.net/blogs/wintergatan.atom"
                  'wintergaten 'blog)
            (list "https://notrelated.xyz/rss"
                  'lukesmith 'notrelated)
            (list "https://lukesmith.xyz/peertube"
                  'lukesmith 'peertube)
            (list "https://www.youtube.com/feeds/videos.xml?channel_id=UC2eYFnH61tmytImy1mTYvhA"
                  'lukesmith 'youtube)
            ;; (list "https://www.youtube.com/feeds/videos.xml?channel_id=UCiWXd0nmBjlKROwzMyPV-Nw"
            ;;       'zhichi 'youtube)
            (list "https://blog.rust-lang.org/feed.xml"
                  'rust 'blog 'official)
            (list "https://sachachua.com/blog/feed/"
                  'sacha 'emacs 'blog)
            (list "https://deterministic.space/feed.xml"
                  'pascal 'rust 'blog 'fun)
            (list "https://fasterthanli.me/index.xml"
                  'amos 'rust 'blog 'lang)
            (list "https://this-week-in-rust.org/atom.xml"
                  'rust 'announce)
            ;; (list "https://www.youtube.com/feeds/videos.xml?channel_id=UCPtfAE6_21oqjO7Bh2bJcog"
            ;;       'teukkaniikka 'arduino)
            ))

;;; Default search filter

(setq elfeed-search-filter "@6-months-ago +emacs")

;;; Show mode hook

(defun durand-elfeed-show-hook (fun &rest arg)
  "Do some set-ups so that I can be happier."
  (require 'olivetti)
  (olivetti-mode 1)
  (let ((shr-width olivetti-body-width))
    (apply fun arg)))

(advice-add #'elfeed-show-refresh :around #'durand-elfeed-show-hook)


;;; switching and deleting

(setq elfeed-show-entry-switch #'switch-to-buffer)
(setq elfeed-show-entry-delete #'elfeed-kill-buffer)

;;; A custom buffer displayer, deprecated

;;;###autoload
(defun elfeed-display-buffer (buffer)
  "Display BUFFER in the bottom window."
  (declare (obsolete
            switch-to-buffer
            "2022-09-03 20:03:53.599131T+28800"))
  (display-buffer
   buffer
   '(display-buffer-reuse-mode-window display-buffer-at-bottom)))

;;; A custom buffer killer, deprecated

;;;###autoload
(defun durand-elfeed-kill-buffer ()
  "Kill the buffer and delete its window."
  (declare (obsolete
            elfeed-kill-buffer
            "2022-09-03 20:07:01.801648T+28800"))
  (kill-buffer (current-buffer))
  (cond
   ((one-window-p))
   ((delete-window (get-buffer-window (current-buffer))))))

;;; Exit elfeed

;;;###autoload
(defun elfeed-search-exit ()
  "Save the database, then kill all related buffers."
  (interactive)
  (elfeed-db-save)
  (mapc
   (function
    (lambda (buffer)
      (cond ((string-match-p "^\\*elfeed" (buffer-name buffer))
             (kill-buffer buffer)))))
   (buffer-list)))

(define-key elfeed-search-mode-map (vector #x78) 'elfeed-search-exit)

;;; Download / play the video in the feed

;;;###autoload
(defun durand-elfeed-play-video (process)
  "Play the video file downloaded by PROCESS."
  (let* ((command (process-command process))
         (link (car (last command)))
         (dir "/Users/durand/Desktop/Centre/Vidéos/")
         (id (process-get process 'id))
         (title (process-get process 'title))
         (ytp (string-match
               (rx-to-string '(seq bos "yt:"
                               (one-or-more (not ":"))
                               ":"
                               (group (one-or-more anything))
                               eos)
                             t)
               id))
         (video-file
          (cond
           (ytp (concat title "-" (match-string 1 id)))
           ("^/xxx")))
         buffer)
    (cond
     ((let* ((files (directory-files dir t video-file t)))
        (and files (= (length files) 1)
             (setq video-file (car files))))
      (setq buffer (generate-new-buffer "*mpv*"))
      (start-process "elfeed-mpv"
                     buffer
                     "mpv"
                     video-file)
      (display-buffer buffer
                      '(durand-display-in-one-window)))
     ((message
       "The file %S does not exist, and id = %s, title = %s"
       video-file id title)))))

;;;###autoload
(defun durand-eshell-download-sentinel (process status)
  "Inform the user when the download process is terminated.
PROCESS should have the name \"elfeed download video\".

This informs the user when STATUS is the string \"finished\\n\"."
  (cond ((string-equal (process-name process) "elfeed download video"))
        ((error "The download sentinel is applied to a wrong process: %S"
                process)))
  (cond ((string-equal status "finished\n")
         (message "Downloading videos has finished."))))

;;;###autoload
(defun durand-eshell-download-play-sentinel (process status)
  "A combination of `durand-eshell-download-sentinel' and \
`durand-elfeed-play-video'."
  (durand-eshell-download-sentinel process status)
  (cond
   ((and (string= status "finished\n")
         (y-or-n-p "Play video?"))
    (durand-elfeed-play-video process))))

;;;###autoload
(defun durand-eshell-download-filter (process output)
  "Display OUTPUT in the buffer associated with PROCESS.
By display it is meant that before inserting the ouput the buffer
will first be erased."
  (let ((buffer (process-buffer process)))
    (cond
     (buffer
      (with-current-buffer buffer
        (erase-buffer)
        (insert
         (replace-regexp-in-string "
\\|" "" output)))))))

;;;###autoload
(defun durand-elfeed-download-video ()
  "Download the video in the feed."
  (interactive)
  (let ((default-directory "/Users/durand/Desktop/Centre/Vidéos/")
        (entry (cond
                ((derived-mode-p 'elfeed-show-mode)
                 elfeed-show-entry)
                ((derived-mode-p 'elfeed-search-mode)
                 (elfeed-search-selected :ignore-region))))
        link proc)
    (cond ((derived-mode-p 'elfeed-search-mode)
           (setq link (elfeed-entry-link (elfeed-search-selected :ignore-region))))
          ((derived-mode-p 'elfeed-show-mode)
           (setq link (elfeed-entry-link elfeed-show-entry)))
          ((user-error "Not in an elfeed buffer")))
    (message "Downloading starts.")
    (setq proc
          (make-process
           :name "elfeed download video"
           :buffer "*elfeed download*"
           :sentinel #'durand-eshell-download-sentinel
           :filter #'durand-eshell-download-filter
           :command (list
                     "yt-dlp" "-f" "bv[height<=720]+ba/b"
                     link)))
    (process-put proc 'id (cdr (elfeed-entry-id entry)))
    (process-put proc 'title (elfeed-entry-title entry))
    proc))

;;;###autoload
(defun durand-elfeed-download-play-video ()
  "Download and confirm to play the video."
  (interactive)
  (let ((proc (durand-elfeed-download-video)))
    (set-process-sentinel proc #'durand-eshell-download-play-sentinel)))

(define-key elfeed-search-mode-map (vector ?w) #'durand-elfeed-download-video)
(define-key elfeed-show-mode-map (vector ?w) #'durand-elfeed-download-video)

(define-key elfeed-search-mode-map (vector ?W) #'durand-elfeed-download-play-video)
(define-key elfeed-show-mode-map (vector ?W) #'durand-elfeed-download-play-video)


(provide 'elfeed-conf)
;;; elfeed-conf.el ends here